57. Operating System Interface

This chapter is about starting and getting out of Emacs, access to values in the operating system environment, and terminal input, output, and flow control.

See section B.1 Building XEmacs, for related information. See also 52. Emacs Display, for additional operating system status information pertaining to the terminal and the screen.

57.1 Starting Up XEmacs

This section describes what XEmacs does when it is started, and how you can customize these actions.

57.1.1 Summary: Sequence of Actions at Start Up

The order of operations performed (in `startup.el') by XEmacs when it is started up is as follows:

1. It loads the initialization library for the window system, if you are using a window system. This library's name is `term/windowsystem-win.el'.

2. It processes the initial options. (Some of them are handled even earlier than this.)

3. It initializes the X window frame and faces, if appropriate.

4. It runs the normal hook before-init-hook.

5. It loads the library `site-start', unless the option `-no-site-file' was specified. The library's file name is usually `site-start.el'.

6. It loads the file `~/.emacs' unless `-q' was specified on the command line. (This is not done in `-batch' mode.) The `-u' option can specify the user name whose home directory should be used instead of `~'.

7. It loads the library `default' unless inhibit-default-init is non-nil. (This is not done in `-batch' mode or if `-q' was specified on the command line.) The library's file name is usually `default.el'.

8. It runs the normal hook after-init-hook.

9. It sets the major mode according to initial-major-mode, provided the buffer `*scratch*' is still current and still in Fundamental mode.

10. It loads the terminal-specific Lisp file, if any, except when in batch mode or using a window system.

11. It displays the initial echo area message, unless you have suppressed that with inhibit-startup-echo-area-message.

12. It processes the action arguments from the command line.

13. It runs term-setup-hook.

14. It calls frame-notice-user-settings, which modifies the parameters of the selected frame according to whatever the init files specify.

15. It runs window-setup-hook. See section 57.1.3 Terminal-Specific Initialization.

16. It displays copyleft, nonwarranty, and basic use information, provided there were no remaining command line arguments (a few steps above) and the value of inhibit-startup-message is nil.

User Option: inhibit-startup-message

This variable inhibits the initial startup messages (the nonwarranty, etc.). If it is non-nil, then the messages are not printed.

This variable exists so you can set it in your personal init file, once you are familiar with the contents of the startup message. Do not set this variable in the init file of a new user, or in a way that affects more than one user, because that would prevent new users from receiving the information they are supposed to see.

User Option: inhibit-startup-echo-area-message

This variable controls the display of the startup echo area message. You can suppress the startup echo area message by adding text with this form to your `.emacs' file:

(setq inhibit-startup-echo-area-message "your-login-name")

Simply setting inhibit-startup-echo-area-message to your login name is not sufficient to inhibit the message; Emacs explicitly checks whether `.emacs' contains an expression as shown above. Your login name must appear in the expression as a Lisp string constant.

This way, you can easily inhibit the message for yourself if you wish, but thoughtless copying of your `.emacs' file will not inhibit the message for someone else.

57.1.2 The Init File: `.emacs'

When you start XEmacs, it normally attempts to load the file `.emacs' from your home directory. This file, if it exists, must contain Lisp code. It is called your init file. The command line switches `-q' and `-u' affect the use of the init file; `-q' says not to load an init file, and `-u' says to load a specified user's init file instead of yours. See section `Entering XEmacs' in The XEmacs User's Manual.

A site may have a default init file, which is the library named `default.el'. XEmacs finds the `default.el' file through the standard search path for libraries (see section 20.1 How Programs Do Loading). The XEmacs distribution does not come with this file; sites may provide one for local customizations. If the default init file exists, it is loaded whenever you start Emacs, except in batch mode or if `-q' is specified. But your own personal init file, if any, is loaded first; if it sets inhibit-default-init to a non-nil value, then XEmacs does not subsequently load the `default.el' file.

Another file for site-customization is `site-start.el'. Emacs loads this before the user's init file. You can inhibit the loading of this file with the option `-no-site-file'.

Variable: site-run-file

This variable specifies the site-customization file to load before the user's init file. Its normal value is "site-start".

If there is a great deal of code in your `.emacs' file, you should move it into another file named `something.el', byte-compile it (see section 21. Byte Compilation), and make your `.emacs' file load the other file using load (see section 20. Loading).

See section `Init File Examples' in The XEmacs User's Manual, for examples of how to make various commonly desired customizations in your `.emacs' file.

User Option: inhibit-default-init

This variable prevents XEmacs from loading the default initialization library file for your session of XEmacs. If its value is non-nil, then the default library is not loaded. The default value is nil.

Variable: before-init-hook

Variable: after-init-hook

These two normal hooks are run just before, and just after, loading of the user's init file, `default.el', and/or `site-start.el'.

57.1.3 Terminal-Specific Initialization

Each terminal type can have its own Lisp library that XEmacs loads when run on that type of terminal. For a terminal type named termtype, the library is called `term/termtype'. XEmacs finds the file by searching the load-path directories as it does for other files, and trying the `.elc' and `.el' suffixes. Normally, terminal-specific Lisp library is located in `emacs/lisp/term', a subdirectory of the `emacs/lisp' directory in which most XEmacs Lisp libraries are kept.

The library's name is constructed by concatenating the value of the variable term-file-prefix and the terminal type. Normally, term-file-prefix has the value "term/"; changing this is not recommended.

The usual function of a terminal-specific library is to enable special keys to send sequences that XEmacs can recognize. It may also need to set or add to function-key-map if the Termcap entry does not specify all the terminal's function keys. See section 57.8 Terminal Input.

When the name of the terminal type contains a hyphen, only the part of the name before the first hyphen is significant in choosing the library name. Thus, terminal types `aaa-48' and `aaa-30-rv' both use the `term/aaa' library. If necessary, the library can evaluate (getenv "TERM") to find the full name of the terminal type.

Your `.emacs' file can prevent the loading of the terminal-specific library by setting the variable term-file-prefix to nil. This feature is useful when experimenting with your own peculiar customizations.

You can also arrange to override some of the actions of the terminal-specific library by setting the variable term-setup-hook. This is a normal hook which XEmacs runs using run-hooks at the end of XEmacs initialization, after loading both your `.emacs' file and any terminal-specific libraries. You can use this variable to define initializations for terminals that do not have their own libraries. See section 33.4 Hooks.

Variable: term-file-prefix

If the term-file-prefix variable is non-nil, XEmacs loads a terminal-specific initialization file as follows:

(load (concat term-file-prefix (getenv "TERM")))

You may set the term-file-prefix variable to nil in your `.emacs' file if you do not wish to load the terminal-initialization file. To do this, put the following in your `.emacs' file: (setq term-file-prefix nil).

Variable: term-setup-hook

This variable is a normal hook that XEmacs runs after loading your `.emacs' file, the default initialization file (if any) and the terminal-specific Lisp file.

You can use term-setup-hook to override the definitions made by a terminal-specific file.

Variable: window-setup-hook

This variable is a normal hook which XEmacs runs after loading your `.emacs' file and the default initialization file (if any), after loading terminal-specific Lisp code, and after running the hook term-setup-hook.

57.1.4 Command Line Arguments

You can use command line arguments to request various actions when you start XEmacs. Since you do not need to start XEmacs more than once per day, and will often leave your XEmacs session running longer than that, command line arguments are hardly ever used. As a practical matter, it is best to avoid making the habit of using them, since this habit would encourage you to kill and restart XEmacs unnecessarily often. These options exist for two reasons: to be compatible with other editors (for invocation by other programs) and to enable shell scripts to run specific Lisp programs.

This section describes how Emacs processes command line arguments, and how you can customize them.

Function: command-line

This function parses the command line that XEmacs was called with, processes it, loads the user's `.emacs' file and displays the startup messages.

Variable: command-line-processed

The value of this variable is t once the command line has been processed.

If you redump XEmacs by calling dump-emacs, you may wish to set this variable to nil first in order to cause the new dumped XEmacs to process its new command line arguments.

Variable: command-switch-alist

The value of this variable is an alist of user-defined command-line options and associated handler functions. This variable exists so you can add elements to it.

A command line option is an argument on the command line of the form:

-option

The elements of the command-switch-alist look like this:

(option . handler-function)

The handler-function is called to handle option and receives the option name as its sole argument.

In some cases, the option is followed in the command line by an argument. In these cases, the handler-function can find all the remaining command-line arguments in the variable command-line-args-left. (The entire list of command-line arguments is in command-line-args.)

The command line arguments are parsed by the command-line-1 function in the `startup.el' file. See also section `Command Line Switches and Arguments' in The XEmacs User's Manual.

Variable: command-line-args

The value of this variable is the list of command line arguments passed to XEmacs.

Variable: command-line-functions

This variable's value is a list of functions for handling an unrecognized command-line argument. Each time the next argument to be processed has no special meaning, the functions in this list are called, in order of appearance, until one of them returns a non-nil value.

These functions are called with no arguments. They can access the command-line argument under consideration through the variable argi. The remaining arguments (not including the current one) are in the variable command-line-args-left.

When a function recognizes and processes the argument in argi, it should return a non-nil value to say it has dealt with that argument. If it has also dealt with some of the following arguments, it can indicate that by deleting them from command-line-args-left.

If all of these functions return nil, then the argument is used as a file name to visit.

57.2 Getting out of XEmacs

There are two ways to get out of XEmacs: you can kill the XEmacs job, which exits permanently, or you can suspend it, which permits you to reenter the XEmacs process later. As a practical matter, you seldom kill XEmacs--only when you are about to log out. Suspending is much more common.

57.2.1 Killing XEmacs

Killing XEmacs means ending the execution of the XEmacs process. The parent process normally resumes control. The low-level primitive for killing XEmacs is kill-emacs.

Command: kill-emacs &optional exit-data

This function exits the XEmacs process and kills it.

If exit-data is a fixnum, then it is used as the exit status of the XEmacs process. (This is useful primarily in batch operation; see 57.11 Batch Mode.)

If exit-data is a string, its contents are stuffed into the terminal input buffer so that the shell (or whatever program next reads input) can read them.

All the information in the XEmacs process, aside from files that have been saved, is lost when the XEmacs is killed. Because killing XEmacs inadvertently can lose a lot of work, XEmacs queries for confirmation before actually terminating if you have buffers that need saving or subprocesses that are running. This is done in the function save-buffers-kill-emacs.

Variable: kill-emacs-query-functions

After asking the standard questions, save-buffers-kill-emacs calls the functions in the list kill-buffer-query-functions, in order of appearance, with no arguments. These functions can ask for additional confirmation from the user. If any of them returns non-nil, XEmacs is not killed.

Variable: kill-emacs-hook

This variable is a normal hook; once save-buffers-kill-emacs is finished with all file saving and confirmation, it runs the functions in this hook.

57.2.2 Suspending XEmacs

Suspending XEmacs means stopping XEmacs temporarily and returning control to its superior process, which is usually the shell. This allows you to resume editing later in the same XEmacs process, with the same buffers, the same kill ring, the same undo history, and so on. To resume XEmacs, use the appropriate command in the parent shell--most likely fg.

Some operating systems do not support suspension of jobs; on these systems, "suspension" actually creates a new shell temporarily as a subprocess of XEmacs. Then you would exit the shell to return to XEmacs.

Suspension is not useful with window systems such as X, because the XEmacs job may not have a parent that can resume it again, and in any case you can give input to some other job such as a shell merely by moving to a different window. Therefore, suspending is not allowed when XEmacs is an X client.

Command: suspend-emacs &optional stuffstring

This function stops XEmacs and returns control to the superior process. If and when the superior process resumes XEmacs, suspend-emacs returns nil to its caller in Lisp.

If optional arg stuffstring is non-nil, its characters are sent to be read as terminal input by XEmacs's superior shell. The characters in stuffstring are not echoed by the superior shell; only the results appear.

Before suspending, suspend-emacs runs the normal hook suspend-hook. In Emacs version 18, suspend-hook was not a normal hook; its value was a single function, and if its value was non-nil, then suspend-emacs returned immediately without actually suspending anything.

After the user resumes XEmacs, suspend-emacs runs the normal hook suspend-resume-hook. See section 33.4 Hooks.

The next redisplay after resumption will redraw the entire screen, unless the variable no-redraw-on-reenter is non-nil (see section 52.1 Refreshing the Screen).

In the following example, note that `pwd' is not echoed after XEmacs is suspended. But it is read and executed by the shell.

(suspend-emacs) => nil (add-hook 'suspend-hook (function (lambda () (or (y-or-n-p "Really suspend? ") (error "Suspend cancelled"))))) => (lambda nil (or (y-or-n-p "Really suspend? ") (error "Suspend cancelled"))) (add-hook 'suspend-resume-hook (function (lambda () (message "Resumed!")))) => (lambda nil (message "Resumed!")) (suspend-emacs "pwd") => nil ---------- Buffer: Minibuffer ---------- Really suspend? y ---------- Buffer: Minibuffer ---------- ---------- Parent Shell ---------- lewis@slug[23] % /user/lewis/manual lewis@slug[24] % fg ---------- Echo Area ---------- Resumed!

Variable: suspend-hook

This variable is a normal hook run before suspending.

Variable: suspend-resume-hook

This variable is a normal hook run after suspending.

57.3 Operating System Environment

XEmacs provides access to variables in the operating system environment through various functions. These variables include the name of the system, the user's UID, and so on.

Variable: system-type

The value of this variable is a symbol indicating the type of operating system XEmacs is operating on. Here is a table of the possible values:

aix

AIX 4.2 or later.

berkeley-unix

Berkeley BSD.

cygwin32

Cygwin.

darwin

Mac OS X.

gnu

A GNU system using the GNU HURD and Mach.

hpux

Hewlett-Packard HPUX operating system, version 11.0 or later.

irix

Silicon Graphics Irix system, version 6.0 or later.

linux

A GNU system using the Linux kernel.

mach

The Mach kernel with a BSD 4.3 layer.

usg-unix-v

AT&T System V.

windows-nt

Microsoft windows NT or one of its descendants.

We do not wish to add new symbols to make finer distinctions unless it is absolutely necessary! In fact, we hope to eliminate some of these alternatives in the future. We recommend using system-configuration to distinguish between different operating systems.

Variable: system-configuration

This variable holds the three-part configuration name for the hardware/software configuration of your system, as a string. The convenient way to test parts of this string is with string-match.

Function: system-name

This function returns the name of the machine you are running on.

(system-name) => "prep.ai.mit.edu"

The symbol system-name is a variable as well as a function. In fact, the function returns whatever value the variable system-name currently holds. Thus, you can set the variable system-name in case Emacs is confused about the name of your system. The variable is also useful for constructing frame titles (see section 39.3 Frame Titles).

Variable: mail-host-address

If this variable is non-nil, it is used instead of system-name for purposes of generating email addresses. For example, it is used when constructing the default value of user-mail-address. See section 57.4 User Identification. (Since this is done when XEmacs starts up, the value actually used is the one saved when XEmacs was dumped. See section B.1 Building XEmacs.)

Command: getenv var &optional interactivep

This function returns the value of the environment variable var, as a string. Within XEmacs, the environment variable values are kept in the Lisp variable process-environment.

When invoked interactively, getenv prints the value in the echo area.

(getenv "USER") => "lewis" lewis@slug[10] % printenv PATH=.:/user/lewis/bin:/usr/bin:/usr/local/bin USER=lewis TERM=ibmapa16 SHELL=/bin/csh HOME=/user/lewis

Command: setenv variable &optional value unset

This command sets the value of the environment variable named variable to value. Both arguments should be strings. This function works by modifying process-environment; binding that variable with let is also reasonable practice.

Variable: process-environment

This variable is a list of strings, each describing one environment variable. The functions getenv and setenv work by manipulating this variable.

process-environment => ("l=/usr/stanford/lib/gnuemacs/lisp" "PATH=.:/user/lewis/bin:/usr/class:/nfsusr/local/bin" "USER=lewis" "TERM=ibmapa16" "SHELL=/bin/csh" "HOME=/user/lewis")

Variable: path-separator

This variable holds a string which says which character separates directories in a search path (as found in an environment variable). Its value is ":" for Unix and GNU systems, and ";" for MS-DOS and Windows NT.

Variable: invocation-name

This variable holds the program name under which Emacs was invoked. The value is a string, and does not include a directory name.

Variable: invocation-directory

This variable holds the directory from which the Emacs executable was invoked, or perhaps nil if that directory cannot be determined.

Variable: installation-directory

If non-nil, this is a directory within which to look for the `lib-src' and `etc' subdirectories. This is non-nil when Emacs can't find those directories in their standard installed locations, but can find them in a directory related somehow to the one containing the Emacs executable.

Function: load-average &optional use-floats

This function returns a list of the current 1-minute, 5-minute and 15-minute load averages. The values are integers that are 100 times the system load averages. (The load averages indicate the number of processes trying to run.)

When use-floats is non-nil, floats will be returned instead of integers. These floats are not multiplied by 100.

(load-average) => (169 158 164) (load-average t) => (1.69921875 1.58984375 1.640625) lewis@rocky[5] % uptime 8:06pm up 16 day(s), 21:57, 40 users, load average: 1.68, 1.59, 1.64

If the 5-minute or 15-minute load averages are not available, return a shortened list, containing only those averages which are available.

On some systems, this function may require special privileges to run, or it may be unimplemented for the particular system type. In that case, the function will signal an error.

Function: emacs-pid

This function returns the process ID of the Emacs process.

57.4 User Identification

Variable: user-mail-address

This holds the nominal email address of the user who is using Emacs. When Emacs starts up, it computes a default value that is usually right, but users often set this themselves when the default value is not right.

Function: user-login-name &optional uid

If you don't specify uid, this function returns the name under which the user is logged in. If the environment variable LOGNAME is set, that value is used. Otherwise, if the environment variable USER is set, that value is used. Otherwise, the value is based on the effective UID, not the real UID.

If you specify uid, the value is the user name that corresponds to uid (which should be a fixnum).

(user-login-name) => "lewis"

Function: user-real-login-name

This function returns the user name corresponding to Emacs's real UID. This ignores the effective UID and ignores the environment variables LOGNAME and USER.

Variable: user-full-name

This variable holds the name of the user running this Emacs. It is initialized at startup time from the value of NAME environment variable. You can change the value of this variable to alter the result of the user-full-name function.

Function: user-full-name &optional user

This function returns the full name of user. If user is nil, it defaults to the user running this Emacs. In that case, the value of user-full-name variable, if non-nil, will be used.

If user is specified explicitly, user-full-name variable is ignored.

(user-full-name) => "Hrvoje Niksic" (setq user-full-name "Hrvoje \"Niksa\" Niksic") (user-full-name) => "Hrvoje \"Niksa\" Niksic" (user-full-name "hniksic") => "Hrvoje Niksic"

The symbols user-login-name, user-real-login-name and user-full-name are variables as well as functions. The functions return the same values that the variables hold. These variables allow you to "fake out" Emacs by telling the functions what to return. The variables are also useful for constructing frame titles (see section 39.3 Frame Titles).

Function: user-real-uid

This function returns the real UID of the user.

(user-real-uid) => 19

Function: user-uid

This function returns the effective UID of the user.

Function: user-home-directory

This function returns the "HOME" directory of the user, and is intended to replace occurrences of "(getenv "HOME")". Under Unix systems, the following is done:

1. Return the value of "(getenv "HOME")", if set.

2. Return "/", as a fallback, but issue a warning. (Future versions of XEmacs will also attempt to lookup the HOME directory via getpwent(), but this has not yet been implemented.)

Under MS Windows, this is done:

1. Return the value of "(getenv "HOME")", if set.

2. If the environment variables HOMEDRIVE and HOMEPATH are both set, return the concatenation (the following description uses MS Windows environment variable substitution syntax): %HOMEDRIVE%%HOMEPATH%.

3. Return "C:\", as a fallback, but issue a warning.

57.5 Time of Day

This section explains how to determine the current time and the time zone.

Function: current-time-string &optional time-value

This function returns the current time and date as a humanly-readable string. The format of the string is unvarying; the number of characters used for each part is always the same, so you can reliably use substring to extract pieces of it. It is wise to count the characters from the beginning of the string rather than from the end, as additional information may be added at the end.

The argument time-value, if given, specifies a time to format instead of the current time. The argument should be a list whose first two elements are fixnums. Thus, you can use times obtained from current-time (see below) and from file-attributes (see section 35.6.4 Other Information about Files).

(current-time-string) => "Wed Oct 14 22:21:05 1987"

Function: current-time

This function returns the system's time value as a list of three integers: (high low microsec). The integers high and low combine to give the number of seconds since 0:00 January 1, 1970, which is high * 2**16 + low.

The third element, microsec, gives the microseconds since the start of the current second (or 0 for systems that return time only on the resolution of a second).

The first two elements can be compared with file time values such as you get with the function file-attributes. See section 35.6.4 Other Information about Files.

Function: current-time-zone &optional time-value

This function returns a list describing the time zone that the user is in.

The value has the form (offset name). Here offset is an integer giving the number of seconds ahead of UTC (east of Greenwich). A negative value means west of Greenwich. The second element, name is a string giving the name of the time zone. Both elements change when daylight savings time begins or ends; if the user has specified a time zone that does not use a seasonal time adjustment, then the value is constant through time.

If the operating system doesn't supply all the information necessary to compute the value, both elements of the list are nil.

The argument time-value, if given, specifies a time to analyze instead of the current time. The argument should be a cons cell containing two fixnums, or a list whose first two elements are fixnums. Thus, you can use times obtained from current-time (see above) and from file-attributes (see section 35.6.4 Other Information about Files).

57.6 Time Conversion

These functions convert time values (lists of two or three fixnums) to strings or to calendrical information. There is also a function to convert calendrical information to a time value. You can get time values from the functions current-time (see section 57.5 Time of Day) and file-attributes (see section 35.6.4 Other Information about Files).

Function: format-time-string format-string &optional time

This function converts time to a string according to format-string. If time is omitted, it defaults to the current time. The argument format-string may contain `%'-sequences which say to substitute parts of the time. Here is a table of what the `%'-sequences mean:

`%a'

This stands for the abbreviated name of the day of week.

`%A'

This stands for the full name of the day of week.

`%b'

This stands for the abbreviated name of the month.

`%B'

This stands for the full name of the month.

`%c'

This is a synonym for `%x %X'.

`%C'

This has a locale-specific meaning. In the default locale (named C), it is equivalent to `%A, %B %e, %Y'.

`%d'

This stands for the day of month, zero-padded.

`%D'

This is a synonym for `%m/%d/%y'.

`%e'

This stands for the day of month, blank-padded.

`%h'

This is a synonym for `%b'.

`%H'

This stands for the hour (00-23).

`%I'

This stands for the hour (00-12).

`%j'

This stands for the day of the year (001-366).

`%k'

This stands for the hour (0-23), blank padded.

`%l'

This stands for the hour (1-12), blank padded.

`%m'

This stands for the month (01-12).

`%M'

This stands for the minute (00-59).

`%n'

This stands for a newline.

`%p'

This stands for `AM' or `PM', as appropriate.

`%r'

This is a synonym for `%I:%M:%S %p'.

`%R'

This is a synonym for `%H:%M'.

`%S'

This stands for the seconds (00-60).

`%t'

This stands for a tab character.

`%T'

This is a synonym for `%H:%M:%S'.

`%U'

This stands for the week of the year (01-52), assuming that weeks start on Sunday.

`%w'

This stands for the numeric day of week (0-6). Sunday is day 0.

`%W'

This stands for the week of the year (01-52), assuming that weeks start on Monday.

`%x'

This has a locale-specific meaning. In the default locale (named C), it is equivalent to `%D'.

`%X'

This has a locale-specific meaning. In the default locale (named C), it is equivalent to `%T'.

`%y'

This stands for the year without century (00-99).

`%Y'

This stands for the year with century.

`%Z'

This stands for the time zone abbreviation.

`%\xe6 (the ISO-8859-1 lowercase ae character)'

This stands for the month as a lowercase Roman number (i-xii)

`%\xc6 (the ISO-8859-1 uppercase AE character)'

This stands for the month as an uppercase Roman number (I-XII)

Function: decode-time &optional specified-time

This function converts a time value into calendrical information. The optional specified-time should be a list of (high low . ignored) or (high . low), as from current-time and file-attributes, or nil to use the current time.

The return value is a list of nine elements, as follows:

(seconds minutes hour day month year dow dst zone)

Here is what the elements mean:

sec

The number of seconds past the minute, as an integer between 0 and 59.

minute

The number of minutes past the hour, as an integer between 0 and 59.

hour

The hour of the day, as an integer between 0 and 23.

day

The day of the month, as an integer between 1 and 31.

month

The month of the year, as an integer between 1 and 12.

year

The year, an integer typically greater than 1900.

dow

The day of week, as an integer between 0 and 6, where 0 stands for Sunday.

dst

t if daylight savings time is effect, otherwise nil.

zone

An integer indicating the time zone, as the number of seconds east of Greenwich.

Note that Common Lisp has different meanings for dow and zone.

Function: encode-time seconds minutes hour day month year &optional zone

This function is the inverse of decode-time. It converts seven items of calendrical data into a time value. For the meanings of the arguments, see the table above under decode-time.

Year numbers less than 100 are treated just like other year numbers. If you want them to stand for years above 1900, you must alter them yourself before you call encode-time.

The optional argument zone defaults to the current time zone and its daylight savings time rules. If specified, it can be either a list (as you would get from current-time-zone) or an integer (as you would get from decode-time). The specified zone is used without any further alteration for daylight savings time.

57.7 Timers for Delayed Execution

You can set up a timer to call a function at a specified future time.

Function: add-timeout secs function object &optional resignal

This function adds a timeout, to be signaled after the timeout period has elapsed. secs is a number of seconds, expressed as an integer or a float. function will be called after that many seconds have elapsed, with one argument, the given object. If the optional resignal argument is provided, then after this timeout expires, add-timeout will automatically be called again with resignal as the first argument.

This function returns an object which is the id of this particular timeout. You can pass that object to disable-timeout to turn off the timeout before it has been signalled.

The number of seconds may be expressed as a floating-point number, in which case some fractional part of a second will be used. Caveat: the usable timeout granularity will vary from system to system.

Adding a timeout causes a timeout event to be returned by next-event, and the function will be invoked by dispatch-event, so if XEmacs is in a tight loop, the function will not be invoked until the next call to sit-for or until the return to top-level (the same is true of process filters).

WARNING: if you are thinking of calling add-timeout from inside of a callback function as a way of resignalling a timeout, think again. There is a race condition. That's why the resignal argument exists.

(NOTE: In FSF Emacs, this function is called run-at-time and has different semantics.)

Function: disable-timeout id

Cancel the requested action for id, which should be a value previously returned by add-timeout. This cancels the effect of that call to add-timeout; the arrival of the specified time will not cause anything special to happen. (NOTE: In FSF Emacs, this function is called cancel-timer.)

57.8 Terminal Input

This section describes functions and variables for recording or manipulating terminal input. See 52. Emacs Display, for related functions.

57.8.1 Input Modes

Function: set-input-mode interrupt flow meta &optional quit-char console

This function sets the mode for reading keyboard input. If interrupt is non-null, then XEmacs uses input interrupts. If it is nil, then it uses CBREAK mode. When XEmacs communicates directly with X, it ignores this argument and uses interrupts if that is the way it knows how to communicate.

If flow is non-nil, then XEmacs uses XON/XOFF (C-q, C-s) flow control for output to the terminal. This has no effect except in CBREAK mode. See section 57.10 Flow Control.

The default setting is system dependent. Some systems always use CBREAK mode regardless of what is specified.

The argument meta controls support for input character codes above 127. If meta is t, XEmacs converts characters with the 8th bit set into Meta characters. If meta is nil, XEmacs disregards the 8th bit; this is necessary when the terminal uses it as a parity bit. If meta is neither t nor nil, XEmacs uses all 8 bits of input unchanged. This is good for terminals using European 8-bit character sets.

If quit-char is non-nil, it specifies the character to use for quitting. Normally this character is C-g. See section 25.8 Quitting.

The current-input-mode function returns the input mode settings XEmacs is currently using.

Function: current-input-mode &optional console

This function returns current mode for reading keyboard input. It returns a list, corresponding to the arguments of set-input-mode, of the form (interrupt flow meta quit) in which:

interrupt

is non-nil when XEmacs is using interrupt-driven input. If nil, Emacs is using CBREAK mode.

flow

is non-nil if XEmacs uses XON/XOFF (C-q, C-s) flow control for output to the terminal. This value has no effect unless interrupt is non-nil.

meta

is t if XEmacs treats the eighth bit of input characters as the meta bit; nil means XEmacs clears the eighth bit of every input character; any other value means XEmacs uses all eight bits as the basic character code.

quit

is the character XEmacs currently uses for quitting, usually C-g.

57.8.2 Translating Input Events

This section describes features for translating input events into other input events before they become part of key sequences.

Variable: function-key-map

This console-local variable holds a keymap that describes the character sequences sent by function keys on an ordinary character terminal. This keymap uses the same data structure as other keymaps, but is used differently: it specifies translations to make while reading events.

If function-key-map "binds" a key sequence k to a vector v, then when k appears as a subsequence anywhere in a key sequence, it is replaced with the events in v.

For example, VT100 terminals send ESC O P when the keypad PF1 key is pressed. Therefore, we want XEmacs to translate that sequence of events into the single event pf1. We accomplish this by "binding" ESC O P to [pf1] in function-key-map, when using a VT100.

Thus, typing C-c PF1 sends the character sequence C-c ESC O P; later the function read-key-sequence translates this back into C-c PF1, which it returns as the vector [?\C-c pf1].

Entries in function-key-map are ignored if they conflict with bindings made in the minor mode, local, or global keymaps. The intent is that the character sequences that function keys send should not have command bindings in their own right.

The value of function-key-map is usually set up automatically according to the terminal's Terminfo or Termcap entry, but sometimes those need help from terminal-specific Lisp files. XEmacs comes with terminal-specific files for many common terminals; their main purpose is to make entries in function-key-map beyond those that can be deduced from Termcap and Terminfo. See section 57.1.3 Terminal-Specific Initialization.

Emacs versions 18 and earlier used totally different means of detecting the character sequences that represent function keys.

Variable: function-key-map-parent

The parent keymap of function-key-map is a non-console-local keymap, function-key-map-parent, and any additions to function-key-map that are not specific to a given console should normally go into function-key-map-parent rather than function-key-map.

Variable: key-translation-map

This variable is another keymap used just like function-key-map to translate input events into other events. It differs from function-key-map in two ways:

• key-translation-map goes to work after function-key-map is finished; it receives the results of translation by function-key-map.

• key-translation-map overrides actual key bindings.

The intent of key-translation-map is for users to map one character set to another, including ordinary characters normally bound to self-insert-command.

You can use function-key-map or key-translation-map for more than simple aliases, by using a function, instead of a key sequence, as the "translation" of a key. Then this function is called to compute the translation of that key.

The key translation function receives one argument, which is the prompt that was specified in read-key-sequence---or nil if the key sequence is being read by the editor command loop. In most cases you can ignore the prompt value.

If the function reads input itself, it can have the effect of altering the event that follows. For example, here's how to define C-c h to turn the character that follows into a Hyper character:

(defun hyperify (prompt)
  (let ((e (read-event)))
    (vector (if (numberp e)
                (logior (lsh 1 20) e)
              (if (memq 'hyper (event-modifiers e))
                  e
                (add-event-modifier "H-" e))))))

(defun add-event-modifier (string e)
  (let ((symbol (if (symbolp e) e (car e))))
    (setq symbol (intern (concat string
                                 (symbol-name symbol))))
    (if (symbolp e)
        symbol
      (cons symbol (cdr e)))))

(define-key function-key-map "\C-ch" 'hyperify)

The `iso-transl' library uses this feature to provide a way of inputting non-ASCII Latin-1 characters.

57.8.3 Recording Input

Function: recent-keys &optional number

This function returns a vector containing recent input events from the keyboard or mouse. By default, 100 events are recorded, which is how many recent-keys returns.

All input events are included, whether or not they were used as parts of key sequences. Thus, you always get the last 100 inputs, not counting keyboard macros. (Events from keyboard macros are excluded because they are less interesting for debugging; it should be enough to see the events that invoked the macros.)

If number is specified, not more than number events will be returned. You may change the number of stored events using set-recent-keys-ring-size.

Function: recent-keys-ring-size

This function returns the number of recent events stored internally. This is also the maximum number of events recent-keys can return. By default, 100 events are stored.

Function: set-recent-keys-ring-size size

This function changes the number of events stored by XEmacs and returned by recent-keys.

For example, (set-recent-keys-ring-size 250) will make XEmacs remember last 250 events and will make recent-keys return last 250 events by default.

Command: open-dribble-file filename

This function opens a dribble file named filename. When a dribble file is open, each input event from the keyboard or mouse (but not those from keyboard macros) is written in that file. A non-character event is expressed using its printed representation surrounded by `<...>'.

You close the dribble file by calling this function with an argument of nil.

This function is normally used to record the input necessary to trigger an XEmacs bug, for the sake of a bug report.

(open-dribble-file "~/dribble") => nil

See also the open-termscript function (see section 57.9 Terminal Output).

57.9 Terminal Output

The terminal output functions send output to the terminal or keep track of output sent to the terminal. The function device-baud-rate tells you what XEmacs thinks is the output speed of the terminal.

Function: device-baud-rate &optional device

This function's value is the output speed of the terminal associated with device, as far as XEmacs knows. device defaults to the selected device (usually the only device) if omitted. Changing this value does not change the speed of actual data transmission, but the value is used for calculations such as padding. This value has no effect for window-system devices. (This is different in FSF Emacs, where the baud rate also affects decisions about whether to scroll part of the screen or repaint, even when using a window system.)

The value is measured in bits per second.

XEmacs attempts to automatically initialize the baud rate by querying the terminal. If you are running across a network, however, and different parts of the network work are at different baud rates, the value returned by XEmacs may be different from the value used by your local terminal. Some network protocols communicate the local terminal speed to the remote machine, so that XEmacs and other programs can get the proper value, but others do not. If XEmacs has the wrong value, it makes decisions that are less than optimal. To fix the problem, use set-device-baud-rate.

Function: set-device-baud-rate device baud-rate

This function sets the output speed of device. See device-baud-rate. device defaults to the selected device (usually the only device) if nil.

Function: send-string-to-terminal char-or-string &optional stdout-p device

This function sends char-or-string to the terminal without alteration. Control characters in char-or-string have terminal-dependent effects.

If device is nil, this function writes to XEmacs's stderr, or to stdout if stdout-p is non-nil. Otherwise, device should be a tty or stream device, and the function writes to the device's normal or error output, according to stdout-p.

One use of this function is to define function keys on terminals that have downloadable function key definitions. For example, this is how on certain terminals to define function key 4 to move forward four characters (by transmitting the characters C-u C-f to the computer):

(send-string-to-terminal "\eF4\^U\^F") => nil

Command: open-termscript filename

This function is used to open a termscript file that will record all the characters sent by XEmacs to the terminal. (If there are multiple tty or stream devices, all characters sent to all such devices are recorded.) The function returns nil. Termscript files are useful for investigating problems where XEmacs garbles the screen, problems that are due to incorrect Termcap entries or to undesirable settings of terminal options more often than to actual XEmacs bugs. Once you are certain which characters were actually output, you can determine reliably whether they correspond to the Termcap specifications in use.

A nil value for filename stops recording terminal output.

See also open-dribble-file in 57.8 Terminal Input.

(open-termscript "../junk/termscript") => nil

57.10 Flow Control

This section attempts to answer the question "Why does XEmacs choose to use flow-control characters in its command character set?" For a second view on this issue, read the comments on flow control in the `emacs/INSTALL' file from the distribution; for help with Termcap entries and DEC terminal concentrators, see `emacs/etc/TERMS'.

At one time, most terminals did not need flow control, and none used C-s and C-q for flow control. Therefore, the choice of C-s and C-q as command characters was uncontroversial. XEmacs, for economy of keystrokes and portability, used nearly all the ASCII control characters, with mnemonic meanings when possible; thus, C-s for search and C-q for quote.

Later, some terminals were introduced which required these characters for flow control. They were not very good terminals for full-screen editing, so XEmacs maintainers did not pay attention. In later years, flow control with C-s and C-q became widespread among terminals, but by this time it was usually an option. And the majority of users, who can turn flow control off, were unwilling to switch to less mnemonic key bindings for the sake of flow control.

So which usage is "right", XEmacs's or that of some terminal and concentrator manufacturers? This question has no simple answer.

One reason why we are reluctant to cater to the problems caused by C-s and C-q is that they are gratuitous. There are other techniques (albeit less common in practice) for flow control that preserve transparency of the character stream. Note also that their use for flow control is not an official standard. Interestingly, on the model 33 teletype with a paper tape punch (which is very old), C-s and C-q were sent by the computer to turn the punch on and off!

As X servers and other window systems replace character-only terminals, this problem is gradually being cured. For the mean time, XEmacs provides a convenient way of enabling flow control if you want it: call the function enable-flow-control.

Command: enable-flow-control &optional argument

This function enables use of C-s and C-q for output flow control, and provides the characters C-\ and C-^ as aliases for them using keyboard-translate-table (see section 57.8.2 Translating Input Events).

With optional argument argument (interactively the prefix argument), enable flow control mode if argument is positive; else disable it.

You can use the function enable-flow-control-on in your `.emacs' file to enable flow control automatically on certain terminal types.

Function: enable-flow-control-on &rest termtypes

This function enables flow control, and the aliases C-\ and C-^, if the terminal type is one of termtypes. For example:

(enable-flow-control-on "vt200" "vt300" "vt101" "vt131")

Here is how enable-flow-control does its job:

1. It sets CBREAK mode for terminal input, and tells the operating system to handle flow control, with (set-input-mode nil t).

2. It sets up keyboard-translate-table to translate C-\ and C-^ into C-s and C-q. Except at its very lowest level, XEmacs never knows that the characters typed were anything but C-s and C-q, so you can in effect type them as C-\ and C-^ even when they are input for other commands. See section 57.8.2 Translating Input Events.

If the terminal is the source of the flow control characters, then once you enable kernel flow control handling, you probably can make do with less padding than normal for that terminal. You can reduce the amount of padding by customizing the Termcap entry. You can also reduce it by setting baud-rate to a smaller value so that XEmacs uses a smaller speed when calculating the padding needed. See section 57.9 Terminal Output.

57.11 Batch Mode

The command line option `-batch' causes XEmacs to run noninteractively. In this mode, XEmacs does not read commands from the terminal, it does not alter the terminal modes, and it does not expect to be outputting to an erasable screen. The idea is that you specify Lisp programs to run; when they are finished, XEmacs should exit. The way to specify the programs to run is with `-l file', which loads the library named file, and `-f function', which calls function with no arguments.

Any Lisp program output that would normally go to the echo area, either using message or using prin1, etc., with t as the stream, goes instead to XEmacs's standard error descriptor when in batch mode. Thus, XEmacs behaves much like a noninteractive application program. (The echo area output that XEmacs itself normally generates, such as command echoing, is suppressed entirely.)

Function: noninteractive

This function returns non-nil when XEmacs is running in batch mode.

Variable: noninteractive

This variable is non-nil when XEmacs is running in batch mode. Setting this variable to nil, however, will not change whether XEmacs is running in batch mode, and will not change the return value of the noninteractive function.