[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34. Documentation

XEmacs Lisp has convenient on-line help facilities, most of which derive their information from the documentation strings associated with functions and variables. This chapter describes how to write good documentation strings for your Lisp programs, as well as how to write programs to access documentation.

Note that the documentation strings for XEmacs are not the same thing as the XEmacs manual. Manuals have their own source files, written in the Texinfo language; documentation strings are specified in the definitions of the functions and variables they apply to. A collection of documentation strings is not sufficient as a manual because a good manual is not organized in that fashion; it is organized in terms of topics of discussion.

34.1 Documentation Basics  Good style for doc strings. Where to put them. How XEmacs stores them.
34.2 Access to Documentation Strings  How Lisp programs can access doc strings.
34.3 Substituting Key Bindings in Documentation  Substituting current key bindings.
34.4 Describing Characters for Help Messages  Making printable descriptions of non-printing characters and key sequences.
34.5 Help Functions  Subroutines used by XEmacs help facilities.
34.6 Obsoleteness  Upgrading Lisp functionality over time.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34.1 Documentation Basics

A documentation string is written using the Lisp syntax for strings, with double-quote characters surrounding the text of the string. This is because it really is a Lisp string object. The string serves as documentation when it is written in the proper place in the definition of a function or variable. In a function definition, the documentation string follows the argument list. In a variable definition, the documentation string follows the initial value of the variable.

When you write a documentation string, make the first line a complete sentence (or two complete sentences) since some commands, such as apropos, show only the first line of a multi-line documentation string. Also, you should not indent the second line of a documentation string, if you have one, because that looks odd when you use C-h f (describe-function) or C-h v (describe-variable). See section A.3 Tips for Documentation Strings.

Documentation strings may contain several special substrings, which stand for key bindings to be looked up in the current keymaps when the documentation is displayed. This allows documentation strings to refer to the keys for related commands and be accurate even when a user rearranges the key bindings. (See section 34.2 Access to Documentation Strings.)

Within the Lisp world, a documentation string is accessible through the function or variable that it describes:

To save space, the documentation for preloaded functions and variables (including primitive functions and autoloaded functions) is stored in the internal doc file `DOC'. The documentation for functions and variables loaded during the XEmacs session from byte-compiled files is stored in those very same byte-compiled files (see section 21.4 Documentation Strings and Compilation).

XEmacs does not keep documentation strings in memory unless necessary. Instead, XEmacs maintains, for preloaded symbols, an integer offset into the internal doc file, and for symbols loaded from byte-compiled files, a list containing the filename of the byte-compiled file and an integer offset, in place of the documentation string. The functions documentation and documentation-property use that information to read the documentation from the appropriate file; this is transparent to the user.

For information on the uses of documentation strings, see section `Help' in The XEmacs Reference Manual.

The `emacs/lib-src' directory contains two utilities that you can use to print nice-looking hardcopy for the file `emacs/etc/DOC-version'. These are `sorted-doc.c' and `digest-doc.c'.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34.2 Access to Documentation Strings

Function: documentation-property symbol property &optional verbatim
This function returns the documentation string that is recorded in symbol's property list under property property. It retrieves the text from a file if necessary, and runs substitute-command-keys to substitute actual key bindings. (This substitution is not done if verbatim is non-nil; the verbatim argument exists only as of Emacs 19.)

 
(documentation-property 'command-line-processed
   'variable-documentation)
     => "t once command line has been processed"
(symbol-plist 'command-line-processed)
     => (variable-documentation 188902)

Function: documentation function &optional verbatim
This function returns the documentation string of function. It reads the text from a file if necessary. Then (unless verbatim is non-nil) it calls substitute-command-keys, to return a value containing the actual (current) key bindings.

The function documentation signals a void-function error if function has no function definition. However, it is ok if the function definition has no documentation string. In that case, documentation returns nil.

Here is an example of using the two functions, documentation and documentation-property, to display the documentation strings for several symbols in a `*Help*' buffer.

 
(defun describe-symbols (pattern)
  "Describe the XEmacs Lisp symbols matching PATTERN.
All symbols that have PATTERN in their name are described
in the `*Help*' buffer."
  (interactive "sDescribe symbols matching: ")
  (let ((describe-func
         (function
          (lambda (s)
            ;; Print description of symbol.
            (if (fboundp s)             ; It is a function.
                (princ
                 (format "%s\t%s\n%s\n\n" s
                   (if (commandp s)
                       (let ((keys (where-is-internal s)))
                         (if keys
                             (concat
                              "Keys: "
                              (mapconcat 'key-description
                                         keys " "))
                           "Keys: none"))
                     "Function")
                   (or (documentation s)
                       "not documented"))))

            (if (boundp s)              ; It is a variable.
                (princ
                 (format "%s\t%s\n%s\n\n" s
                   (if (user-variable-p s)
                       "Option " "Variable")
                   (or (documentation-property
                         s 'variable-documentation)
                       "not documented")))))))
        sym-list)

    ;; Build a list of symbols that match pattern.
    (mapatoms (function
               (lambda (sym)
                 (if (string-match pattern (symbol-name sym))
                     (setq sym-list (cons sym sym-list))))))

    ;; Display the data.
    (with-output-to-temp-buffer "*Help*"
      (mapcar describe-func (sort sym-list 'string<))
      (print-help-return-message))))

The describe-symbols function works like apropos, but provides more information.

 
(describe-symbols "goal")

---------- Buffer: *Help* ----------
goal-column     Option
*Semipermanent goal column for vertical motion, as set by C-x C-n, or nil.

set-goal-column Command: C-x C-n
Set the current horizontal position as a goal for C-n and C-p.
Those commands will move to this position in the line moved to
rather than trying to keep the same horizontal position.
With a non-nil argument, clears out the goal column
so that C-n and C-p resume vertical motion.
The goal column is stored in the variable `goal-column'.

temporary-goal-column   Variable
Current goal column for vertical motion.
It is the column where point was
at the start of current run of vertical motion commands.
When the `track-eol' feature is doing its job, the value is 9999.
---------- Buffer: *Help* ----------

Function: Snarf-documentation filename
This function is used only during XEmacs initialization, just before the runnable XEmacs is dumped. It finds the file offsets of the documentation strings stored in the file filename, and records them in the in-core function definitions and variable property lists in place of the actual strings. See section B.1 Building XEmacs.

XEmacs finds the file filename in the `lib-src' directory. When the dumped XEmacs is later executed, the same file is found in the directory doc-directory. The usual value for filename is `DOC', but this can be changed by modifying the variable internal-doc-file-name.

Variable: internal-doc-file-name
This variable holds the name of the file containing documentation strings of built-in symbols, usually `DOC'. The full pathname of the internal doc file is `(concat doc-directory internal-doc-file-name)'.

Variable: doc-directory
This variable holds the name of the directory which contains the internal doc file that contains documentation strings for built-in and preloaded functions and variables.

In most cases, this is the same as exec-directory. They may be different when you run XEmacs from the directory where you built it, without actually installing it. See exec-directory in 34.5 Help Functions.

In older Emacs versions, exec-directory was used for this.

Variable: data-directory
This variable holds the name of the directory in which XEmacs finds certain system independent documentation and text files that come with XEmacs. In older Emacs versions, exec-directory was used for this.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34.3 Substituting Key Bindings in Documentation

When documentation strings refer to key sequences, they should use the current, actual key bindings. They can do so using certain special text sequences described below. Accessing documentation strings in the usual way substitutes current key binding information for these special sequences. This works by calling substitute-command-keys. You can also call that function yourself.

Here is a list of the special sequences and what they mean:

\[command]
stands for a key sequence that will invoke command, or `M-x command' if command has no key bindings.

\{mapvar}
stands for a summary of the value of mapvar, which should be a keymap. The summary is made by describe-bindings.

\<mapvar>
stands for no text itself. It is used for a side effect: it specifies mapvar as the keymap for any following `\[command]' sequences in this documentation string.

\=
quotes the following character and is discarded; this `\=\=' puts `\=' into the output, and `\=\[' puts `\[' into the output.

Please note: Each `\' must be doubled when written in a string in XEmacs Lisp.

Function: substitute-command-keys string
This function scans string for the above special sequences and replaces them by what they stand for, returning the result as a string. This permits display of documentation that refers accurately to the user's own customized key bindings.

Here are examples of the special sequences:

 
(substitute-command-keys
   "To abort recursive edit, type: \\[abort-recursive-edit]")
=> "To abort recursive edit, type: C-]"

(substitute-command-keys
   "The keys that are defined for the minibuffer here are:
  \\{minibuffer-local-must-match-map}")
=> "The keys that are defined for the minibuffer here are:

?               minibuffer-completion-help
SPC             minibuffer-complete-word
TAB             minibuffer-complete
LFD             minibuffer-complete-and-exit
RET             minibuffer-complete-and-exit
C-g             abort-recursive-edit
"

(substitute-command-keys
   "To abort a recursive edit from the minibuffer, type\
\\<minibuffer-local-must-match-map>\\[abort-recursive-edit].")
=> "To abort a recursive edit from the minibuffer, type C-g."

(substitute-command-keys
  "Substrings of the form \\=\\{MAPVAR} are replaced by summaries
\(made by `describe-bindings') of the value of MAPVAR, taken as a keymap.
Substrings of the form \\=\\<MAPVAR> specify to use the value of MAPVAR
as the keymap for future \\=\\[COMMAND] substrings.
\\=\\= quotes the following character and is discarded;
thus, \\=\\=\\=\\= puts \\=\\= into the output,
and \\=\\=\\=\\[ puts \\=\\[ into the output.")
=> "Substrings of the form \{MAPVAR} are replaced by summaries
(made by `describe-bindings') of the value of MAPVAR, taken as a keymap.
Substrings of the form \<MAPVAR> specify to use the value of MAPVAR
as the keymap for future \[COMMAND] substrings.
\= quotes the following character and is discarded;
thus, \=\= puts \= into the output,
and \=\[ puts \[ into the output."


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34.4 Describing Characters for Help Messages

These functions convert events, key sequences or characters to textual descriptions. These descriptions are useful for including arbitrary text characters or key sequences in messages, because they convert non-printing and whitespace characters to sequences of printing characters. The description of a non-whitespace printing character is the character itself.

Function: key-description sequence
This function returns a string containing the XEmacs standard notation for the input events in sequence. The argument sequence may be a string, vector or list. See section 25.5 Events, for more information about valid events. See also the examples for single-key-description, below.

Function: single-key-description key
This function returns a string describing key in the standard XEmacs notation for keyboard input. A normal printing character appears as itself, but a control character turns into a string starting with `C-', a meta character turns into a string starting with `M-', and space, linefeed, etc. appear as `SPC', `LFD', etc. A symbol appears as the name of the symbol. An event that is a list appears as the name of the symbol in the CAR of the list.

 
(single-key-description ?\C-x)
     => "C-x"
(key-description "\C-x \M-y \n \t \r \f123")
     => "C-x SPC M-y SPC LFD SPC TAB SPC RET SPC C-l 1 2 3"
(single-key-description 'kp-next)
     => "kp-next"
(single-key-description '(shift button1))
     => "Sh-button1"

Function: text-char-description character
This function returns a string describing character in the standard XEmacs notation for characters that appear in text--like single-key-description, except that control characters are represented with a leading caret (which is how control characters in XEmacs buffers are usually displayed).

 
(text-char-description ?\C-c)
     => "^C"
(text-char-description ?\M-m)
     => "M-m"
(text-char-description ?\C-\M-m)
     => "M-^M"


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34.5 Help Functions

XEmacs provides a variety of on-line help functions, all accessible to the user as subcommands of the prefix C-h, or on some keyboards, help. For more information about them, see section `Help' in The XEmacs Lisp Reference Manual. Here we describe some program-level interfaces to the same information.

Command: apropos regexp &optional do-all predicate
This function finds all symbols whose names contain a match for the regular expression regexp, and returns a list of them (see section 44.2 Regular Expressions). It also displays the symbols in a buffer named `*Help*', each with a one-line description.

If do-all is non-nil, then apropos also shows key bindings for the functions that are found.

If predicate is non-nil, it should be a function to be called on each symbol that has matched regexp. Only symbols for which predicate returns a non-nil value are listed or displayed.

In the first of the following examples, apropos finds all the symbols with names containing `exec'. In the second example, it finds and returns only those symbols that are also commands. (We don't show the output that results in the `*Help*' buffer.)

 
(apropos "exec")
     => (Buffer-menu-execute command-execute exec-directory
    exec-path execute-extended-command execute-kbd-macro
    executing-kbd-macro executing-macro)

(apropos "exec" nil 'commandp)
     => (Buffer-menu-execute execute-extended-command)

apropos is used by various user-level commands, such as C-h a (hyper-apropos), a graphical front-end to apropos; and C-h A (command-apropos), which does an apropos over only those functions which are user commands. command-apropos calls apropos, specifying a predicate to restrict the output to symbols that are commands. The call to apropos looks like this:

 
(apropos string t 'commandp)

Variable: help-map
The value of this variable is a local keymap for characters following the Help key, C-h.

Prefix Command: help-command
This symbol is not a function; its function definition is actually the keymap known as help-map. It is defined in `help.el' as follows:

 
(define-key global-map "\C-h" 'help-command)
(fset 'help-command help-map)

Function: print-help-return-message &optional function
This function builds a string that explains how to restore the previous state of the windows after a help command. After building the message, it applies function to it if function is non-nil. Otherwise it calls message to display it in the echo area.

This function expects to be called inside a with-output-to-temp-buffer form, and expects standard-output to have the value bound by that special operator. For an example of its use, see the long example in 34.2 Access to Documentation Strings.

Variable: help-char
The value of this variable is the help character--the character that XEmacs recognizes as meaning Help. By default, it is the character `?\^H' (ASCII 8), which is C-h. When XEmacs reads this character, if help-form is non-nil Lisp expression, it evaluates that expression, and displays the result in a window if it is a string.

help-char can be a character or a key description such as help or (meta h).

Usually the value of help-form's value is nil. Then the help character has no special meaning at the level of command input, and it becomes part of a key sequence in the normal way. The standard key binding of C-h is a prefix key for several general-purpose help features.

The help character is special after prefix keys, too. If it has no binding as a subcommand of the prefix key, it runs describe-prefix-bindings, which displays a list of all the subcommands of the prefix key.

Variable: help-form
If this variable is non-nil, its value is a form to evaluate whenever the character help-char is read. If evaluating the form produces a string, that string is displayed.

A command that calls next-command-event or next-event probably should bind help-form to a non-nil expression while it does input. (The exception is when C-h is meaningful input.) Evaluating this expression should result in a string that explains what the input is for and how to enter it properly.

Entry to the minibuffer binds this variable to the value of minibuffer-help-form (see section 24.9 Minibuffer Miscellany).

Variable: prefix-help-command
This variable holds a function to print help for a prefix character. The function is called when the user types a prefix key followed by the help character, and the help character has no binding after that prefix. The variable's default value is describe-prefix-bindings.

Command: describe-prefix-bindings
This function calls describe-bindings to display a list of all the subcommands of the prefix key of the most recent key sequence. The prefix described consists of all but the last event of that key sequence. (The last event is, presumably, the help character.)

The following two functions are found in the library `helper'. They are for modes that want to provide help without relinquishing control, such as the "electric" modes. You must load that library with (require 'helper) in order to use them. Their names begin with `Helper' to distinguish them from the ordinary help functions.

Command: Helper-describe-bindings
This command pops up a window displaying a help buffer containing a listing of all of the key bindings from both the local and global keymaps. It works by calling describe-bindings.

Command: Helper-help
This command provides help for the current mode. It prompts the user in the minibuffer with the message `Help (Type ? for further options)', and then provides assistance in finding out what the key bindings are, and what the mode is intended for. It returns nil.

This can be customized by changing the map Helper-help-map.


[ < ] [ > ]   [ << ] [ Up ] [ >> ]         [Top] [Contents] [Index] [ ? ]

34.6 Obsoleteness

As you add functionality to a package, you may at times want to replace an older function with a new one. To preserve compatibility with existing code, the older function needs to still exist; but users of that function should be told to use the newer one instead. XEmacs Lisp lets you mark a function or variable as obsolete, and indicate what should be used instead.

Command: make-obsolete function new &optional when
This function indicates that function is an obsolete function, and the function new should be used instead. The byte compiler will issue a warning to this effect when it encounters a usage of the older function, and the help system will also note this in the function's documentation. new can also be a string (if there is not a single function with the same functionality any more), and should be a descriptive statement, such as "use foo or bar instead" or "this function is unnecessary". If provided, when should be a string indicating when the function was first made obsolete, for example a date or a release number.

Command: make-obsolete-variable variable new
This is like make-obsolete but is for variables instead of functions.

Function: define-obsolete-function-alias oldfun newfun
This function combines make-obsolete and define-function, declaring oldfun to be an obsolete variant of newfun and defining oldfun as an alias for newfun.

Function: define-obsolete-variable-alias oldvar newvar
This is like define-obsolete-function-alias but for variables.

Note that you should not normally put obsoleteness information explicitly in a function or variable's doc string. The obsoleteness information that you specify using the above functions will be displayed whenever the doc string is displayed, and by adding it explicitly the result is redundancy.

Also, if an obsolete function is substantially the same as a newer one but is not actually an alias, you should consider omitting the doc string entirely (use a null string `""' as the doc string). That way, the user is told about the obsoleteness and is forced to look at the documentation of the new function, making it more likely that he will use the new function.

Function: function-obsoleteness-doc function
If function is obsolete, this function returns a string describing this. This is the message that is printed out during byte compilation or in the function's documentation. If function is not obsolete, nil is returned.

Function: variable-obsoleteness-doc variable
This is like function-obsoleteness-doc but for variables.

The obsoleteness information is stored internally by putting a property byte-obsolete-info (for functions) or byte-obsolete-variable (for variables) on the symbol that specifies the obsolete function or variable. For more information, see the implementation of make-obsolete and make-obsolete-variable in `lisp/bytecomp/bytecomp-runtime.el'.


[ << ] [ >> ]           [Top] [Contents] [Index] [ ? ]

This document was generated by XEmacs Webmaster on August, 3 2012 using texi2html